; Fast WritePixelArray8

	move.l	(a0)+,d0	; Get abcd/70
	move.l	(a0)+,d1	; Get efgh/70
	move.l	(a0)+,d2	; Get ijkl/70
	move.l	(a0)+,d3	; Get mnop/70
	move.l	#$ff00ff00,d6	; Put mask/8
	move.l	d0,d4
	move.l	d2,d5
	and.l	d6,d0		; Calc a.c./70
	and.l	d6,d5		; Calc i.k./70
	eor.l	d0,d4		; Calc .b.d/70
	eor.l	d5,d2		; Calc .j.l/70
	lsr.l	#8,d5
	lsl.l	#8,d4
	or.l	d5,d0		; Calc aick/70
	or.l	d4,d2		; Calc bjdl/70
	move.l	d1,d4
	move.l	d3,d5
	and.l	d6,d1
	and.l	d6,d5
	eor.l	d1,d4
	eor.l	d5,d3
	lsr.l	#8,d5
	lsl.l	#8,d4
	or.l	d5,d1		; Calc emgo/70
	or.l	d4,d3		; Calc fnhp/70
	move.l	#$0f0f0f0f,d6	; Put mask/4
	move.l	d0,d4
	move.l	d1,d5
	and.l	d6,d0		; Calc .a.i.c.k/30
	and.l	d6,d5		; Calc .e.m.g.o/30
	eor.l	d0,d4		; Calc a.i.c.k./74
	eor.l	d5,d1		; Calc e.m.g.o./74
	lsr.l	#4,d1
	lsl.l	#4,d0
	or.l	d5,d0		; Calc aeimcgko/30
	or.l	d4,d1		; Calc aeimcgko/74
	move.l	d2,d4
	move.l	d3,d5
	and.l	d6,d2
	and.l	d6,d5
	eor.l	d2,d4
	eor.l	d5,d3
	lsr.l	#4,d3
	lsl.l	#4,d2
	or.l	d5,d2		; Calc bfjndhlp/30
	or.l	d4,d3		; Calc bfjndhlp/74
	move.l	#$3333cccc,d6	; Put mask/2
	move.l	d0,d4
	move.l	d2,d5
	and.l	d6,d0		; Calc .a.e.i.m/10 c.g.k.o./32
	and.l	d6,d2		; Calc .b.f.j.n/10 d.h.l.p./32
	eor.l	d0,d4		; Calc a.e.i.m./32 .c.g.k.o/10
	eor.l	d2,d5		; Calc b.f.j.n./32 .d.h.l.p/10
	lsr.w	#2,d0
	lsr.w	#2,d2
	swap	d0
	swap	d2
	lsl.w	#2,d0		; Calc .c.g.k.o/32 a.e.i.m./10
	lsl.w	#2,d2		; Calc .d.h.l.p/32 b.f.j.n./10
	or.l	d4,d0		; Calc acegikmo/32 acegikmo/10
	or.l	d5,d2		; Calc bdfhjlnp/32 bdfhjlnp/10
	move.l	#$55555555,d7
	move.l	d0,d4
	move.l	d2,d5
	and.l	d7,d0		; Calc .a.c.e.g.i.k.m.o/2 .a.c.e.g.i.k.m.o/0
	and.l	d7,d5		; Calc .b.d.f.h.j.l.n.p/2 .b.d.f.h.j.l.n.p/0 
	eor.l	d0,d4
	eor.l	d5,d2
	lsr.l	#1,d2
	add.l	d0,d0
	or.l	d5,d0		; Calc abcdefghijklmnop/2 abcdefghijklmnop/0
	or.l	d4,d2		; Calc abcdefghijklmnop/3 abcdefghijklmnop/1
	move.l	d1,d4
	move.l	d3,d5
	and.l	d6,d1
	and.l	d6,d3
	eor.l	d1,d4
	eor.l	d3,d5
	lsr.w	#2,d1
	lsr.w	#2,d3
	swap	d1
	swap	d3
	lsl.w	#2,d1
	lsl.w	#2,d3
	or.l	d4,d1
	or.l	d5,d3
	move.l	d1,d4
	move.l	d3,d5
	and.l	d7,d1
	and.l	d7,d5
	eor.l	d1,d4
	eor.l	d5,d3
	lsr.l	#1,d3
	add.l	d1,d1
	or.l	d5,d1		; Calc abcdefghijklmnop/6 abcdefghijklmnop/4
	or.l	d4,d3 		; Calc abcdefghijklmnop/7 abcdefghijklmnop/5
	rts